Lazarus / FPC - run a command and read it's output, working with system tray; laptop's battery on OpenSuSE 12.x - 13.1

     For unknown reasons, KDE on OpenSuSE 12.x and 13.1 (so far) does not recognize correctly the battery of my Acer laptop. It says “Battery not present”, wich is not true. After some unsuccessful attempts to fix this, I gave up and decided to write my own program. 

     In order for my program to work, it must:

1) Run a LINUX command line to obtain the battery statistics and load the output

2) Analyse the output an identify the values that are needed

3) Create a simple interface to display the results

4) Minimise the main form to system tray (and then maximise if needed)

5) Change the system tray icon to display the level of the battery for quick view and artistic impression :-)

You need:

- a form

- a memo

- 2 buttons

- a ImageList from Common Controls

- a timer

- a TrayIcon from Additional

Doubleclick on ImageList to load the images you like for different battery states (I created my own, size 16x32)

The full program can be downloaded from here

https://www.dropbox.com/sh/d5bw7h3j33vmu5t/AACGFf4616J6QtJWtqaTVLjqa/Battery?dl=0

If you are not interested in the source code, you need only the file BatteryF

Here is the full code

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ExtCtrls, Buttons, Process, strutils;

type

  { TForm1 }

  TForm1 = class(TForm)
    ImageList1: TImageList;
    Memo1: TMemo;
    Panel1: TPanel;
    SpeedButton1: TSpeedButton;
    SpeedButton2: TSpeedButton;
    Timer1: TTimer;
    TrayIcon1: TTrayIcon;
    procedure FormShow(Sender: TObject);
    procedure SpeedButton1Click(Sender: TObject);
    procedure SpeedButton2Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure TrayIcon1Click(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end;

var
  Form1: TForm1;
  Bmp: tbitmap;
  Bat: integer;

function get1:tstringlist;

implementation

{$R *.lfm}

{ TForm1 }

function get1:tstringlist;
var l:tstringlist; Proc1: tprocess; t1,t2:string; i,j,k:integer;
begin
   bmp :=tbitmap.Create;
   form1.Memo1.Lines.Clear;

   /// run a command line and read the output
   /// first we must determine if a battery is present or detected

   l:=tstringlist.Create;
   proc1:=tprocess.Create(form1);

   proc1.Executable:='upower';
   proc1.Parameters.Add('-e');

   proc1.Options := proc1.Options + [poWaitOnExit, poUsePipes];
   proc1.Execute;
   l.LoadFromStream(proc1.Output);    /// load the output to stringlist
   t1:='';
   for i:=0 to l.Count-1 do
   begin
     t2:=l[i];
     if AnsiContainsText(t2,'BAT') then t1:=t2;  /// BAT is for battery
   end;

/// if a battery is detected
  if t1<>'' then
   begin
     form1.trayicon1.Hint:='';
     proc1.Parameters.Clear;
     proc1.Parameters.Add('-i');  /// for more details see upower documentation
     proc1.Parameters.Add(t1);
     proc1.Execute;
     l.LoadFromStream(proc1.Output);

     for i:=0 to l.Count-1 do
     begin
       t2:=l[i];
       if AnsiContainsText(t2,'percentage') then      /// find the battery level
        begin
          j:=length(t2);
          bat:=strtoint(midstr(t2,j-3,3));
          form1.Caption:='Battery level: '+inttostr(bat)+'%';
          form1.trayicon1.Hint:=form1.trayicon1.Hint+t2+chr(13);
        end;
       if AnsiContainsText(t2,'time to empty') then
            form1.trayicon1.Hint:=form1.trayicon1.Hint+t2+chr(13);
     end;
/// "form caption" and "trayicon hint" are for artistic impression :-)
/// if upower displays the results in a different language (I don't know if it can),
    // the program will find nothing when searching for "percentage" and "time to empty"
    // so you must modify the keyword acording to your language
   k:=0;
   if bat>20 then k:=1; /// select the image number from timagelist for system tray
   if bat>35 then k:=2;
   if bat>50 then k:=3;
   if bat>70 then k:=4;
   if bat>90 then k:=5;
   if bat=100 then k:=7;

   form1.imagelist1.GetBitmap(k,bmp);   /// get the image from timagelist
   form1.trayicon1.Icon.assign(bmp);    /// assign the image to system tray

   end

  else
      begin
        l.Add('Battery not detected or not present');
        form1.imagelist1.GetBitmap(6,bmp);
        form1.trayicon1.Icon.assign(bmp);
      end;

   proc1.Free;
   bmp.Free;
   result:=l;

end;

procedure TForm1.FormShow(Sender: TObject);
begin
    memo1.Text:=get1.Text;   /// display the full statistics
end;

procedure TForm1.SpeedButton1Click(Sender: TObject);
begin
  form1.close;    /// terminate the program
end;

procedure TForm1.SpeedButton2Click(Sender: TObject);
begin
  form1.Hide;     /// minimise to system tray
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
   memo1.Text:=get1.Text;   /// refresh the status every 60 seconds
end;

procedure TForm1.TrayIcon1Click(Sender: TObject);
begin
  form1.Show;      /// show the main form when click on tray icon
end;

end.